Report

Conversion of DOB to full words [Solved]

Ask a question jigs - Last answered on Feb 26, 2016 04:51AM
Hello,

I want to to convert dob to word like 5/6/2014 to fifth June two thousand fourteen please tell me solution
See more 
Helpful
+0
moins plus
Hello Jigs,

This will require a UDF (User Defined Function), not just a simple formula.

Read the following post (post #2) by Rick Rothstein way back in 2012. He has supplied an excellent solution for the OP which will work for you also.

http://www.mrexcel.com/forum/excel-questions/615519-convert-date-words.html

Place the UDF in a standard module. I have modified it as follows to allow for proper English grammar and punctuation in the end result:-


Function DateToWords(ByVal DateIn As Variant) As String
  Dim Yrs As String
  Dim Hundreds As String
  Dim Decades As String
  Dim Tens As Variant
  Dim Ordinal As Variant
  Dim Cardinal As Variant
  Ordinal = Array("First", "Second", "Third", _
                   "Fourth", "Fifth", "Sixth", _
                   "Seventh", "Eighth", "Nineth", _
                   "Tenth", "Eleventh", "Twelfth", _
                   "Thirteenth", "Fourteenth", _
                   "Fifteenth", "Sixteenth", _
                   "Seventeenth", "Eighteenth", _
                   "Nineteenth", "Twentieth", _
                   "Twenty first", "Twenty second", _
                   "Twenty third", "Twenty fourth", _
                   "Twenty fifth", "Twenty sixth", _
                   "Twenty seventh", "Twenty eighth", _
                   "Twenty nineth", "Thirtieth", _
                   "Thirty first")
  Cardinal = Array("", "One", "Two", "Three", "Four", _
                   "Five", "Six", "Seven", "Eight", "Nine", _
                   "Ten", "Eleven", "Twelve", "Thirteen", _
                   "Fourteen", "Fifteen", "Sixteen", _
                   "Seventeen", "Eighteen", "Nineteen")
  Tens = Array("Twenty", "Thirty", "Forty", "Fifty", _
               "Sixty", "Seventy", "Eighty", "Ninety")
  DateIn = CDate(DateIn)
  Yrs = CStr(Year(DateIn))
  Decades = Mid$(Yrs, 3)
  If CInt(Decades) < 20 Then
    Decades = Cardinal(CInt(Decades))
  Else
    Decades = Tens(CInt(Left$(Decades, 1)) - 2) & " " & _
              Cardinal(CInt(Right$(Decades, 1)))
  End If
  Hundreds = Mid$(Yrs, 2, 1)
  If CInt(Hundreds) Then
    Hundreds = Cardinal(CInt(Hundreds)) & " Hundred and "
  Else
    Hundreds = ""
  End If
  DateToWords = Ordinal(Day(DateIn) - 1) & " day of " & _
                Format$(DateIn, "mmmm, ") & _
                Cardinal(CInt(Left$(Yrs, 1))) & _
                " Thousand, " & Hundreds & Decades
End Function


If your date is in say, cell A1, place this formula in cell B1 (or wherever you like):
=DateToWords(A1)


Read Rick's post carefully and remember that this is his work solely.

I hope that this helps.

Cheerio,
vcoolio.
Jigs- Feb 22, 2016 04:45AM
Hello while using this Formula I got oñly one answer please help me to solve this error
Reply
Jigs- Feb 23, 2016 07:34AM
Thank you friend I got my solution.
Reply
Add comment
Helpful
+0
moins plus
Hello Jigs,

You will only get one result per cell. To get more than one result, drag the formula down as far as needed, e.g. B1 dragged down to B20. There will only ever be one result per cell.

Cheerio,
vcoolio.
Jigs- Feb 22, 2016 10:57AM
No friends i'm saying that i'm finding only one answer for any date I enterd like for 7/10/1993 I got any other answer and for other date answer remain same
Reply
Add comment
Helpful
+0
moins plus
Hello Jigs,

Have you tampered with the UDF?

Following is the link to my test work book:-

https://www.dropbox.com/s/46sytj1nfo9zx2q/Convert%20Date%20to%20Words%28completely%20using%20UDF%29.xlsm?dl=0

You'll see that whatever date you enter in Column A, the correct wording will appear in Column C. The UDF and the formula associated with it work perfectly.

As I said previously, you need to drag the formula down as far as needed in Column C (or whichever Column you require) to cover the required cells in Column A (or whichever Column you have your dates in). Just make sure that the correct cell is referenced in the formula. Don't leave blanks between cells.

Cheerio,
vcoolio.
Jigs- Feb 25, 2016 11:00PM
I have another problem that is I want to make all words capital and I have completed 90% of work on it but only month name is not becoming capital so please help me on this issue.
Reply
Add comment
Helpful
+0
moins plus
Hello Jigs,

If you want the month name completely in capitals, then change line 45 of
the code above to:-

UCase(Format$(DateIn, "mmmm, ")) & _


The rest you seem to have sorted out yourself.

Cheerio,
vcoolio.
Add comment

Member requests are more likely to be responded to.

Members can monitor the statuses of their requests from their account pages.

A CCM membership gives you access to additional options.

Not a member yet?

Sign up now. It takes less than a minute and is completely free!