Comparing two cell in different spreadsheets

Option Explicit

Public Function projectLookup(nameCell As Range, dateCell As Range) As String

   Dim sourceSheet         As String
   Dim nameRow             As Long
   Dim maxRows             As Long
   
   sourceSheet = "Sheet1"
   projectLookup = vbNullString
   With Sheets(sourceSheet)
      maxRows = getItemLocation("*", .Cells)
      If maxRows = 0 Then Exit Function
      nameRow = 1
      
      Do
         nameRow = getItemLocation(nameCell.Value, .Range(.Cells(nameRow, "A"), .Cells(maxRows, "A")), bLastOccurance:=False)
         If (nameRow > 0) Then
            If (.Cells(nameRow, "C") = dateCell) Then
               projectLookup = .Cells(nameRow, "B")
               nameRow = 0
            ElseIf (nameRow = maxRows) Then
               nameRow = 0
            Else
               nameRow = nameRow + 1
            End If
         End If
      Loop While (nameRow <> 0)
   End With
End Function

Public Function getItemLocation(sLookFor As String, _
                                rngSearch As Range, _
                                Optional bFullString As Boolean = True, _
                                Optional bLastOccurance As Boolean = True, _
                                Optional bFindRow As Boolean = True) As Long
                                   
   'find the first/last row/column  within a range for a specific string
      
   Dim Cell             As Range
   Dim iLookAt          As Integer
   Dim iSearchDir       As Integer
   Dim iSearchOdr       As Integer
         
   If (bFullString) _
   Then
      iLookAt = xlWhole
   Else
      iLookAt = xlPart
   End If
   If (bLastOccurance) _
   Then
      iSearchDir = xlPrevious
   Else
      iSearchDir = xlNext
   End If
   If Not (bFindRow) _
   Then
      iSearchOdr = xlByColumns
   Else
      iSearchOdr = xlByRows
   End If
         
   With rngSearch
      If (bLastOccurance) _
      Then
         Set Cell = .Find(sLookFor, .Cells(1, 1), xlValues, iLookAt, iSearchOdr, iSearchDir)
      Else
         Set Cell = .Find(sLookFor, .Cells(.Rows.Count, .Columns.Count), xlValues, iLookAt, iSearchOdr, iSearchDir)
      End If
   End With
         
   If Cell Is Nothing Then
      getItemLocation = 0
   ElseIf Not (bFindRow) _
   Then
      getItemLocation = Cell.Column
   Else
      getItemLocation = Cell.Row
   End If
   Set Cell = Nothing

End Function