List/Fill Numbers Between Two Values

public Sub FillInNumbers()
    
    Dim sourceSheetName                 As String
    Dim desitinationSheetName           As String
    
    Dim startPoint                      As Double
    Dim endPoint                        As Double
    Dim maximumSourceRow                As Long
    Dim processRow                      As Long
    Dim sourceRow                       As Long
    Dim deltaRow                        As Double
    
    sourceSheetName = "Sheet1"
    desitinationSheetName = "Sheet2"
    
    With Sheets(sourceSheetName)
        maximumSourceRow = getItemLocation("*", .Range(.Cells(1, "A"), .Cells(.Rows.Count, "B")))
        If (maximumSourceRow < 2) Then Exit Sub
    End With
    
    With Sheets(desitinationSheetName)
        .Columns(1).Clear
        .Columns(1).NumberFormat = "#"
        processRow = 0
        For sourceRow = 2 To maximumSourceRow
            startPoint = Sheets(sourceSheetName).Cells(sourceRow, "A")
            endPoint = Sheets(sourceSheetName).Cells(sourceRow, "B")
            deltaRow = endPoint - startPoint
            processRow = processRow + 1
            .Cells(processRow, "A").Value = startPoint
            .Cells(processRow, "A").AutoFill Destination:=.Range(.Cells(processRow, "A"), .Cells(processRow + deltaRow, "A")), Type:=xlFillSeries
            processRow = processRow + deltaRow
        Next sourceRow
    End With
    
    
    
End Sub

Public Function getItemLocation(sLookFor As String, _
                                rngSearch As Range, _
                                Optional bFullString As Boolean = True, _
                                Optional bLastOccurance As Boolean = True, _
                                Optional bFindRow As Boolean = True) As Long
                                   
   'find the first/last row/column  within a range for a specific string
      
   Dim Cell             As Range
   Dim iLookAt          As Integer
   Dim iSearchDir       As Integer
   Dim iSearchOdr       As Integer
         
   If (bFullString) _
   Then
      iLookAt = xlWhole
   Else
      iLookAt = xlPart
   End If
   If (bLastOccurance) _
   Then
      iSearchDir = xlPrevious
   Else
      iSearchDir = xlNext
   End If
   If Not (bFindRow) _
   Then
      iSearchOdr = xlByColumns
   Else
      iSearchOdr = xlByRows
   End If
         
   With rngSearch
      If (bLastOccurance) _
      Then
         Set Cell = .Find(sLookFor, .Cells(1, 1), xlValues, iLookAt, iSearchOdr, iSearchDir)
      Else
         Set Cell = .Find(sLookFor, .Cells(.Rows.Count, .Columns.Count), xlValues, iLookAt, iSearchOdr, iSearchDir)
      End If
   End With
         
   If Cell Is Nothing Then
      getItemLocation = 0
   ElseIf Not (bFindRow) _
   Then
      getItemLocation = Cell.Column
   Else
      getItemLocation = Cell.Row
   End If
   Set Cell = Nothing

End Function