Compare cell against multiple columns

Function FindHeader(LookForValue As Variant, LookInRange As Range) As Variant 
' PURPOSE:  To find a value in a given range and if found return the value 
'           found in first row of the the column in which the value exists. 
'           If value is not found then "" is returned 
'CALL:      =FindHeader(B2,E:S ) 

Dim rFound As Range ' where the value being searched found 
Dim firstCellAddress As String 'the address of the first cell in the range being looked 
Dim cell As Range ' cell of first 

    'The first part of the range being looked 
    firstCellAddress = Left(LookInRange.Address, InStr(1, LookInRange.Address, ":") - 1) 
         
    ' making sure if the last character is a number. If it is not a number then range is of 
    ' sort A:Z instead of A1:Z50 
    If Not (IsNumeric(Right(firstCellAddress, 1))) Then 
         
        firstCellAddress = firstCellAddress & 1 
     
    End If 
     
    ' looking for the value 
    Set rFound = LookInRange.Find( _ 
                            What:=LookForValue, _ 
                            After:=Range(firstCellAddress), _ 
                            LookIn:=xlFormulas, _ 
                            LookAt:=xlWhole, _ 
                            SearchOrder:=xlByRows, _ 
                            SearchDirection:=xlNext, _ 
                            MatchCase:=False, _ 
                            SearchFormat:=False) 
     
    If (rFound Is Nothing) Then 
         
        FindHeader = "" 
     
    Else 
     
        FindHeader = Cells(1, rFound.Column) 
         
    End If 

    Set rFound = Nothing

End Function