Send file direct on email with attachment

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
If Target.Address = "$C$65" Then
    Call MailOut  ' in this case if A1 is clicked
End If
End Sub

Option Explicit

Sub MailOut()
'Working in 2000-2010
    Dim sh As Worksheet
    Dim wb As Workbook
    Dim FileExtStr As String
    Dim FileFormatNum As Long
    Dim TempFilePath As String
    Dim TempFileName As String
    Dim OutApp As Object
    Dim OutMail As Object

    TempFilePath = Environ$("temp") & "\"

    If Val(Application.Version) < 12 Then
        'You use Excel 97-2003
        FileExtStr = ".xls": FileFormatNum = -4143
    Else
        'You use Excel 2007-2010
        FileExtStr = ".xlsm": FileFormatNum = 52
    End If

    With Application
        .ScreenUpdating = False
        .EnableEvents = False
    End With

    Set OutApp = CreateObject("Outlook.Application")

    For Each sh In ThisWorkbook.Worksheets
        
            sh.Copy
            Set wb = ActiveWorkbook

            TempFileName = sh.Name & " " & Format(Now, "mm-dd-yyyy")

            Set OutMail = OutApp.CreateItem(0)

            With wb
                .SaveAs TempFilePath & TempFileName & FileExtStr, FileFormat:=FileFormatNum

                On Error Resume Next
                With OutMail
                    .To = "FDan@anovo.com"
                    .CC = ""
                    .BCC = ""
                    .Subject = "RMA Survey"
                    .Body = "RMA Survey attached."
                    .Attachments.Add wb.FullName
                    'You can add other files also like this
                    '.Attachments.Add ("C:\test.txt")
                    .Display 'Make sure to comment this if you are using .Send below
                    '.Send 'uncomment .send if you want to send directly without pressing Send button
                End With
                On Error GoTo 0

                .Close SaveChanges:=False
            End With
            Set OutMail = Nothing

            Kill TempFilePath & TempFileName & FileExtStr

    Next sh

    Set OutApp = Nothing

    With Application
        .ScreenUpdating = True
        .EnableEvents = True
    End With
End Sub