Problem search data by selected combobox & datepicker tools

Option Explicit
Dim sh As Worksheet

Sub fill_ListBox()
  Dim i As Long, dtp1 As Date, dtp2 As Date, cmb As Variant
  
  ListBox1.Clear
  
  For i = 2 To sh.Range("G" & Rows.Count).End(xlUp).Row
    If DTPicker1.Value = "" Then
      dtp1 = sh.Range("C" & i).Value
      dtp2 = sh.Range("C" & i).Value
    ElseIf DTPicker2.Value = "" Then
      dtp1 = DTPicker1.Value
      dtp2 = DTPicker1.Value
    Else
      dtp1 = DTPicker1.Value
      dtp2 = DTPicker2.Value
    End If
    If ComboBox1.Value = "" Or ComboBox1.ListIndex = -1 Then
      cmb = sh.Range("G" & i).Value
    Else
      cmb = ComboBox1.Value
    End If
    
    If sh.Range("C" & i).Value >= dtp1 And sh.Range("C" & i).Value <= dtp2 And _
       sh.Range("G" & i).Value = cmb Then
      With ListBox1
        .AddItem sh.Range("A" & i).Value
        .List(.ListCount - 1, 1) = sh.Range("B" & i).Value 'Data from Col B
        .List(.ListCount - 1, 2) = sh.Range("C" & i).Value 'Data from Col C
        .List(.ListCount - 1, 3) = sh.Range("D" & i).Value 'Data from Col D
        .List(.ListCount - 1, 4) = sh.Range("E" & i).Value 'Data from Col E
        .List(.ListCount - 1, 5) = sh.Range("F" & i).Value 'Data from Col f
        .List(.ListCount - 1, 6) = sh.Range("G" & i).Value 'Data from Col g
      End With
    End If
  Next
End Sub

Private Sub ComboBox1_Change()
  fill_ListBox
End Sub

Private Sub DTPicker1_Change()
  fill_ListBox
End Sub

Private Sub DTPicker2_Change()
  fill_ListBox
End Sub

Private Sub UserForm_Initialize()
  Dim i As Long, dic As Object
  
  Set sh = sheet1
  Set dic = CreateObject("Scripting.Dictionary")
  
  For i = 2 To sh.Range("G" & Rows.Count).End(xlUp).Row
    dic(sh.Range("G" & i).Value) = Empty
  Next
  ComboBox1.List = dic.keys
  ListBox1.ColumnCount = 7
  fill_ListBox
End Sub